How To Download Any Windows 10 Version With Media Creation Tool

The blog post will walk through steps on how to download any Windows 10 version with Media Creation tool.

How To Download Any Windows 10 Version With Media Creation Tool

Media Creation Tool is an official Windows 10 ISO downloader. Users can use it in two ways:

  • Create Windows 10 Installation USB Drive
  • Download the Windows 10 ISO image, so that you can burn DVD or create the bootable USB drive later manually.

Microsoft has developed this tool to make it easier for the users to update their computers to the latest version. Either create the bootable USB drive using the device or download the ISO image of the latest version.

No doubt it’s a useful tool, but it lacks one thing. Let’s discuss what that is.

Whenever the company releases a new major update for Windows 10, the Media Creation tool lets users download only the latest version.

With the release of the latest version of Windows 10, the company also update the Media Creation tool and restrict it to download only the current version. This means if you want to download the ISO image for the older versions, then it won’t help you.

For example, as of writing this blog post, the latest version is Windows 10 October 2018 update. Now if you use Media Creation Tool, then it will create USB or download iso for the same version.

There will be no option to download Windows 10 April 2018 update or older.

Although, the ISO images for Windows 10 older version still exists, due to company restriction, the MCT is unable to download them for you.

With the help of quick workaround, you will be able to download any version of Windows 10 using Media Creation tool.

Download Any Windows 10 Version With Media Creation Tool

Reddit user Aveyo has written the BAT file. You can download code of the BAT file directly using this Pastebin link. Also, I’m going to share the same script in the blog post, in case the link stops working in the future.

1. Open Notepad file. For that, click on the desktop and from the context menu select New -> Text Document.

2. Here, you need to copy-paste the following code:

@echo off &title MediaCreationTool.bat by AveYo v2018.10.03
:: Universal wrapper for all "RedStone" versions: 1607, 1703, 1709, 1803 and 1809
:: Using nothing but microsoft-hosted original files for the current and past Windows 10 MCT releases
:: Ingenious full support for creating business channel (Enterprise) with custom language, x86, x64 or AIO!

:: Add / remove launch parameters below if needed - it is preset for least amount of issues when doing upgrades
set "OPTIONS=/Telemetry Disable /DynamicUpdate Disable /MigrateDrivers all /ResizeRecoveryPartition disable /ShowOOBE none"

:: Uncomment to show live mct console log for debugging
rem set "OPTIONS=%OPTIONS% /Console"

:: Uncomment to bypass gui dialog choice and hardcode the target version: 1=1607, 2=1703, 3=1709, 4=1803, 5=1809
rem set/a MCT_VERSION=5

:: Available MCT versions
set versions= 1607 [ RedStone 1 ], 1703 [ RedStone 2 ], 1709 [ RedStone 3 ], 1803 [ RedStone 4 ], 1809 [ RedStone 5 ]

:: Show gui dialog %1:title %2:header %3:choices %4:output_variable
if not defined MCT_VERSION call :choice "MediaCreationTool.bat" "Choose Windows 10 Version" "%versions%" MCT_VERSION
if not defined MCT_VERSION echo No MCT_VERSION selected, exiting.. & timeout /t 5 & exit/b
goto version%MCT_VERSION%

:version1 [RS1]
set "V=1607"
set "D=20170116"
set "EULA=https://wscont.apps.microsoft.com/winstore/OSUpgradeNotification/MediaCreationTool/prod"
set "EULA_FIX=https://download.microsoft.com/download/C/0/3/C036B882-9F99-4BC9-A4B5-69370C4E17E9"
set "CAB=https://wscont.apps.microsoft.com/winstore/OSUpgradeNotification/MediaCreationTool/prod/Products_20170116.cab"
set "MCT=http://download.microsoft.com/download/C/F/9/CF9862F9-3D22-4811-99E7-68CE3327DAE6/MediaCreationTool.exe"
echo Version %V% %D% selected!
goto process

:version2 [RS2]
set "V=1703"
set "D=20170317"
set "EULA=https://wscont.apps.microsoft.com/winstore/OSUpgradeNotification/MediaCreationTool/prod"
set "EULA_FIX=https://download.microsoft.com/download/C/0/3/C036B882-9F99-4BC9-A4B5-69370C4E17E9"
set "CAB=http://download.microsoft.com/download/9/5/4/954415FD-D9D7-4E1F-8161-41B3A4E03D5E/products_20170317.cab"
set "MCT=http://download.microsoft.com/download/1/C/4/1C41BC6B-F8AB-403B-B04E-C96ED6047488/MediaCreationTool.exe"
:: 1703 MCT is also bugged so use 1607 instead
set "MCT=http://download.microsoft.com/download/C/F/9/CF9862F9-3D22-4811-99E7-68CE3327DAE6/MediaCreationTool.exe"
echo Version %V% %D% selected!
goto process

:version3 [RS3]
set "V=1709"
set "D=20180105"
set "EULA="
set "CAB=https://download.microsoft.com/download/3/2/3/323D0F94-95D2-47DE-BB83-1D4AC3331190/products_20180105.cab"
set "MCT=http://download.microsoft.com/download/A/B/E/ABEE70FE-7DE8-472A-8893-5F69947DE0B1/MediaCreationTool.exe"
echo Version %V% %D% selected!
goto process

:version4 [RS4]
set "V=1803"
set "D=20180705"
set "EULA="
set "CAB=https://download.microsoft.com/download/5/C/B/5CB83D2A-2D7E-4129-9AFE-353F8459AA8B/products_20180705.cab"
set "MCT=https://software-download.microsoft.com/download/pr/MediaCreationTool1803.exe"
echo Version %V% %D% selected!
goto process

:version5 [RS5]
set "V=1809"
set "D=20180924"
set "EULA="
set "CAB=https://download.microsoft.com/download/6/F/B/6FB97F08-E010-48A4-A9DC-18FCA920CEB4/products_20180924.cab"
set "MCT=https://software-download.microsoft.com/download/pr/MediaCreationTool1809.exe"
echo Version %V% %D% selected!
goto process

:process
echo.
echo Notice: MCT depends on BITS service! If any issues, run script as Admin..
bitsadmin.exe /reset /allusers 2>nul
net stop bits /y 2>nul
net start bits /y 2>nul

:: cleanup - can include temporary files too but it's not advised since you can't resume via C:\$Windows.~WS\Sources\setuphost
pushd "%~dp0"
del /f /q products.* 2>nul &rem rd /s/q C:\$Windows.~WS 2>nul & rd /s/q C:\$WINDOWS.~BT 2>nul
:: download MCT
set "WEBCLIENT=[Net.ServicePointManager]::SecurityProtocol='tls12,tls11,tls';(new-object System.Net.WebClient)"
if not exist MediaCreationTool%V%.exe powershell -noprofile -c "%WEBCLIENT%.DownloadFile('%MCT%','MediaCreationTool%V%.exe');"
if not exist MediaCreationTool%V%.exe color 0c & echo Error! missing MediaCreationTool%V%.exe & pause & exit /b
:: download CAB
if not exist products_%D%.cab powershell -noprofile -c "%WEBCLIENT%.DownloadFile('%CAB%','products_%D%.cab');"
if not exist products_%D%.cab color 0c & echo Error! missing products_%D%.cab & pause & exit /b
:: unpack CAB
expand.exe -R products_%D%.cab -F:* . >nul 2>nul
if not exist products.xml color 0c & echo Error! bad or missing products_%D%.cab & pause & exit /b
set "READ_XML=$f=[System.IO.File]::ReadAllText('products.xml')"
set "WRITE_XML=[System.IO.File]::WriteAllText('products.xml', $f)"
:: patch XML to fix old EULA links breaking MCT in 1607 and 1703
set "r1= $f=$f.Replace('%EULA%','%EULA_FIX%');" & if not defined EULA set "r1="
:: patch XML to allow selecting business channel editions (Enterprise) and an edition name cosmetic fix
set "r2= $f=$f.Replace('IsRetailOnly>True<','IsRetailOnly>False<');"
set "r3= $f=$f -ireplace '%%ENTERPRISE_?([A-Z]*)_?([A-Z]*)%%','Windows 10 Enterprise $1 $2';"
powershell -c "%READ_XML%; %r1% %r2% %r3% %WRITE_XML%;"
:: repack XML into CAB
start "" /wait makecab products.xml products.cab
:: finally launch MCT with local configuration and optional launch options
start "" MediaCreationTool%V%.exe /Selfhost %OPTIONS%
exit/b

:: utilities
::------------------------------------------------------------------------------------------------------------------------------
:choice %1:title %2:header %3:choices %4:output_variable [GUI radioboxes dialog snippet by AveYo] released under MIT License
setlocal &set "parameters=$title='%~1'; $header='%~2'; $choices='%~3'; $global:c='';"
set "s1=[void][System.Reflection.Assembly]::LoadWithPartialName('System.Windows.Forms');$f=New-Object System.Windows.Forms.Form"
set "s2=;$f.Text=$title; $f.Forecolor='Snow'; $f.BackColor=0xff180052; $f.StartPosition='CenterScreen'; $f.AutoSize=$true;"
set "s3=$g=New-Object System.Windows.Forms.GroupBox; $g.Location='40,10'; $g.Margin='0,0,40,0'; $g.MinimumSize='280,100';"
set "s4=$g.AutoSize=$true; $g.text=$header; $f.Controls.Add($g);"
set "s5=$i=1; foreach($l in $choices.split(',')){ $r=New-Object System.Windows.Forms.RadioButton; $r.Location='20,'+(30*$i);"
set "s6=$r.Name=$i;$r.Text=$l;$r.AutoSize=$true;$r.add_Click({$global:c=$this.Name}); $g.Controls.Add($r); $r.Checked=1; $i++};"
set "s7=$j=1;foreach($t in @('OK','Exit')){$b=New-Object System.Windows.Forms.Button;$b.Location=''+(120*($j-1)+80)+','+40*$i;"
set "s8=$b.Name='b'+$j; $b.Text=$t; $b.DialogResult=$j; if ($j -eq 1){$f.AcceptButton=$b}; $f.Controls.Add($b); $j++};"
set "s9=$f.Add_Shown({$f.Activate()}); $ret=$f.ShowDialog(); if ($ret -eq 2){$global:c=''}; write-host $global:c"
for /l %%# in (1,1,9) do call set "ps_Choice=%%ps_Choice%%%%s%%#:"=\"%%"
for /f "usebackq tokens=* delims=" %%# in (`powershell -noprofile -c "%parameters% %ps_Choice%"`) do set "output_var=%%#"
endlocal & set "%~4=%output_var%" & exit/b
::------------------------------------------------------------------------------------------------------------------------------

:: v2018.10.03:
:: - using media refresh for 1803 [RS4]
:: - edition name cosmetic fix for business channel

3. Now save the file with .bat extension. Here’s how to do that.

Click on the File available on the upper left corner, then select Save as. This will open the ‘Browse window‘, here

  • Select the location, where you want to save the file. The desktop is always good.
  • Rename the file and save it with a .bat file.

For example, you can name it MCT, and after adding a .bat extension, it will become MCT.bat. And click Save. Check the screenshot for a clear idea:

4. Now you will a BAT file on your selected location. You need to run the file as Administrator. For that, right click on the file and choose “Run as administrator.

When UAC dialog box comes, click Yes to continue.

5. This will open a Command Prompt window with a list of Windows 10 versions you want to download. Using this, you can download from Windows 10 Redstone 1 to Windows 10 Redstone 5.

  • Redstone 1 – Windows 10 Anniversary Update
  • Redstone 2 – Windows 10 Creators Update
  • Redstone 3 – Windows 10 Fall Creators Update
  • Redstone 4 – Windows 10 April 2018 Update
  • Redstone 5 – Windows 10 October 2018 Update

Select one; you want to download and press the OK button.

6. It will automatically run few commands on the Command prompt window and run the Media creation tool. Follow the on-screen instructions to download the ISO or creating a bootable USB stick.

Happy Downloading 😉

Leave a Reply

Your email address will not be published. Required fields are marked *

This site uses Akismet to reduce spam. Learn how your comment data is processed.